Chapter - Ending B (Progue-centric)
Section - Dream
[If ENDING B, the conversation is with a grown Lethe, and about the loopholes in wayfaring, and designed to make the player realize Progue might still have a chance to be reunited with his daughters. ]
EPLP is a thread with escape clause eplp_escape. [Epilogue - Like Progue] Instead of exhausting when last beat is in EPLP: force discuss eplp_escape. Instead of getting bored when last beat is in EPLP: force discuss eplp_escape. eplp_escape is a repeatable dogged ephemeral beat in EPLP with reaction "'Well,' she says, 'but there is more to say.'". eplp_escape enqueues eplp_intro.
eplp_intro is an exciting beat in EPLP with reaction "Before you stands a beautiful [o]woman[x], slowly running a comb with a carved dolphin for a handle through her long black hair. Her features are strangely familiar, and you finally realize you have seen her before. In dreams.". eplp_intro suggests eplp_samechoice. eplp_lessons replaces eplp_intro.
ep-lethe is a woman with printed name "Lethe". Understand "Lethe/girl/woman/daughter" as ep-lethe. The description is "Lethe. How she must look now, as a grown woman-- but some part of you realizes this is not really her-- just a dream. No tricks, no messages, but dream, just and only.".
To say eplp_intro2: say "'How strange are meetings that come too late,' she says quietly, running the brush smoothly through her hair and not quite meeting your gaze. 'For you have already been me in dreams, seen my most intimate drawings from childhood to my first masterpiece, loved me through the eyes of my father, and through his hands and words and memories as well.' She nods, as if to herself. 'Yes, introductions now would be quite redundant. Especially since somehow I feel I know you equally well.'[paragraph break]'For instance,' she says quietly, looking into your eyes for the first time, '".
eplp_diffchoice is a beat in EPLP with reaction "[eplp_intro2]I know of a moment, worlds and time ago, when you also made this choice between art and love, and chose differently. In Rume's bed you chose [if we chose art]art, and now, now, you choose love[else]love, and now, now, you choose art[end if]. So what changed, then? Did something of my [eplp_father] seep within you to alter your priorities? Or maybe something in those two great [eplp_societies] vying for control of that island? Or,' she says with a wry smile, 'perhaps this was so long ago you no longer [eplp_remember] why you once chose the way you did?'". eplp_diffchoice suggests eplp_choicenoans.
eplp_samechoice is a beat in EPLP with reaction "[eplp_intro2]we have met many wayfarers now, my sister and I. And they are mercurial, many perhaps schizophrenic; the only way they stay sane in lives defined by change is to change themselves. Yet on a cold night worlds and time ago, when you also made this choice between love and art, you chose the same way. How can you remain yourself? Through strength of [eplp_conviction], mayhaps, or something simpler: it merely felt [eplp_right] to you then as it does now? Or,' she adds with a wry smile, 'perhaps this was so long ago you no longer [eplp_remember] why you once chose the way you did?'". eplp_samechoice suggests eplp_choicenoans.
eplp_choicenoans is a beat in EPLP with reaction "'Well, no matter,' she says, the brush moving rhythmically through her long hair. 'None of my business, I suppose.'". eplp_choicenoans enqueues eplp_whenyoumet.
Understand "father" as eplp_father when last beat is in EPLP. eplp_father is a beat in EPLP with keyword name "father" and reaction "She looks away, touches of sadness hardening the smoothness of her face, the brush moving rhythmically through her long hair. 'My father changes all who meet him,' she says finally, 'for better or for worse.' She closes her eyes for a moment, then opens them again, stronger. 'No,' she says, 'My anger at him has long since melted away, though he has not yet burned his guilt. [if second-choice-love is true]Love is the right choice, friend. It burns most brightly of all[else]Art can burn them both away, my friend, but so many other things as well. Take care what you set aflame[end if].'". eplp_father enqueues eplp_whenyoumet.
Understand "society/societies" as eplp_societies when last beat is in EPLP. eplp_societies is a beat in EPLP with keyword name "societies" and reaction "She stares into the void intently, the brush moving smoothly now through her hair. 'I dreamed with you through those two worlds,' she says. 'And I kept wondering who it was who had Called you. My father? That quiet, sad leader of a struggling, violent people? The whisper of windsigh trees across a milky spiral of stars[if The-Path-Of-Love has happened]? Even my sister, or I, all those years ago[end if]?' She shakes her head. 'Or all or none of them,' she says. 'The Call defies understanding. But it always changes you; I've learned that, and my sister too. Always is change.'". eplp_societies enqueues eplp_whenyoumet.
Understand "conviction" as eplp_conviction when last beat is in EPLP. eplp_conviction is a beat in EPLP with keyword name "conviction" and reaction "She considers, the brush moving smoothly now through her hair. 'I'm not sure I believe in conviction,' she says. 'Certainly not in absolute moralities or universal truths; I've moved through enough worlds to be disabused of such comforting notions. Phoebe would disagree. But. Now inner conviction, consistency of self-- hmm.' She smiles to herself. 'It's a rare quality in we who wayfare,' she adds finally. 'Treasure it, friend.'". eplp_conviction enqueues eplp_whenyoumet.
Understand "correct" as eplp_right when last beat is in EPLP. eplp_right is a beat in EPLP with keyword name "correct" and reaction "She smiles knowingly, the brush moving smoothly now through her hair. 'How strange it is,' she murmurs, 'to look back into the dusty corners of our lives, and find some past self who utterly and completely agrees with us. Or mayhaps it's not strange at all for most people, but for me, I find change the only constant. It's always something shocking to discover I was once the same person.' She laughs, but softly, quietly, and the lilting sound soon dies away.". eplp_right enqueues eplp_whenyoumet.
Understand "remember" as eplp_remember when last beat is in EPLP. eplp_remember is a beat in EPLP with keyword name "remember" and reaction "She laughs aloud; not spitefully, a kind, simple laugh alive with lilting echoes and harmonies. 'I think Phoebe would like you,' she says. 'You both prefer to go clothed in plain and simple truths rather than over-thought justifications and rationalizations. I like you too, I suppose, even if only because you remind me of her.'". eplp_remember enqueues eplp_whenyoumet.
eplp_whenyoumet is a beat in EPLP with reaction "She turns serious, staring down at the brush in her hands and running an idle finger over its intricate details. 'When you met my father he was only half a man. Or--' she smiles a little, not looking up, '--two thirds of one, as he put it. He had lost so much.'".
After discussing eplp_whenyoumet:
if neurotic dad begin; force discuss eplp_neuroticdad;
else if father knows best; force discuss eplp_fatherknowsbest;
else if bitter dad; force discuss eplp_bitterdad;
else if disciplinarian; force discuss eplp_disciplinarian;
else if friend; force discuss eplp_friend;
else if toady; force discuss eplp_toady;
else if lover or twitterpated; force discuss eplp_lover;
else if enemy; force discuss eplp_enemy;
else if slave; force discuss eplp_slave;
else if bitter lover or shattered lover; force discuss eplp_bitterlover;
else; force discuss eplp_friend;
continue the action.
eplp_neuroticdad is a beat in EPLP with reaction "'Yet somehow he came to think of you like a [if player is male]son[else]daughter[end if],' she says, 'although he didn't quite remember how to be a father again. ". eplp_neuroticdad enqueues eplp_intended.
eplp_fatherknowsbest is a beat in EPLP with reaction "'Yet somehow he came to think of you like a [if player is male]son[else]daughter[end if],' she says, 'and he remembered the best and worst parts of his fatherhood.". eplp_fatherknowsbest enqueues eplp_intended.
eplp_bitterdad is a beat in EPLP with reaction "'Yet somehow he came to think of you like a [if player is male]son[else]daughter[end if],' she says, 'though a disrespectful one, mayhaps. You frustrated him, I think, because he thought he knew what was best, even though you didn't always get along and he didn't always have the courage to tell you.'". eplp_bitterdad enqueues eplp_intended.
eplp_disciplinarian is a beat in EPLP with reaction "'Yet somehow he came to think of you like a [if player is male]son[else]daughter[end if],' she says, 'though a disobedient one. Like my sister and I; you awoke old frustrations in him, I think, though at least the two of us could sometimes get along with him.'". eplp_disciplinarian enqueues eplp_intended.
eplp_friend is a beat in EPLP with reaction "'Yet you became a friend to him, when he needed a friend,' she says, 'and I thank you for that.'". eplp_friend enqueues eplp_intended.
eplp_toady is a beat in EPLP with reaction "Yet you became a friend to him, of a sort, when he needed a friend,' she says. 'No, more than need; he was so desperate for companionship that he was perhaps too quick to let you have your way.'". eplp_toady enqueues eplp_intended.
eplp_lover is a beat in EPLP with reaction "She smiles quietly at you. 'He saw something in you,' she says, 'that reminded him of... [if player is female]my mother, perhaps, or maybe you're nothing like her at all[else]himself, perhaps, or maybe his first love, lost worlds ago[end if]. I'm not sure; I don't know you.' She takes a deep breath. 'But whatever it was, I thank you for showing it to him. After our mother died, his grief was a weight that crushed us all, and he had no sense of how to take any of the weight off his daughters. Maybe no parents in such circumstances do, maybe...' She bites her lip and trails off. 'I don't know,' she finally says. 'All I can offer, again, is my thanks. For making him happy again.'". eplp_lover enqueues eplp_intended.
eplp_enemy is a beat in EPLP with reaction "'But you did not see eye to eye, you two,' she says sadly, 'and I think that has always been his curse. He is so headstrong that he cannot let other people in; cannot understand them or believe in them. Even my sister and I...' She bites her lip. 'A difficult man,' she finally concludes.". eplp_enemy enqueues eplp_intended.
eplp_slave is a beat in EPLP with reaction "'But you did not see eye to eye, you two,' she says sadly, 'and he became almost like a slave to you, didn't he? So eager and desperate to please you, even though he feared and distrusted you. Mayhaps he was too far gone to be a friend to anyone.'". eplp_slave enqueues eplp_intended.
eplp_bitterlover is a beat in EPLP with reaction "She smiles quietly at you. 'He saw something in you,' she says, 'that reminded him of... [if player is female]my mother, perhaps, or maybe you're nothing like her at all[else]himself, perhaps, or maybe his first love, lost worlds ago[end if]. I'm not sure; I don't know you.' She takes a deep breath. 'But it didn't last. No, of course it couldn't; it was only a dream. And he ended more hurt than when he began. It was hard for him. I'm not sure whether I should hate you or whether he deserved it.'". eplp_bitterlover enqueues eplp_intended.
eplp_intended is an insistent beat in EPLP with reaction "'Now he is-- perhaps not whole, not yet, but at least he is refilling. Scabs have been torn off but the flow has reversed, and the world once again flows through his tender wounds to mingle with his blood.'[paragraph break]'Is that how you thought it would work out,' she asks, turning her head to the side, 'when you first saw him, standing on that boulder and shouting at the sea?'". The yes-beat of eplp_intended is eplp_intyes. The no-beat of eplp_intended is eplp_intno. eplp_intended summons eplp_intyes, eplp_intno.
Instead of getting bored when last beat is eplp_intended or last beat is eplp_pleased, force discuss eplp_lessons.
eplp_intyes is a beat in EPLP with keyword name "yes". eplp_intyes enqueues eplp_pleased.
eplp_intno is a beat in EPLP with keyword name "no". eplp_intno enqueues eplp_pleased.
eplp_pleased is an insistent beat in EPLP with reaction "'[if eplp_intyes is spoken]And[else]But then[end if] are you happy with the way things turned out[if eplp_intno is spoken], anyway[end if]?' she asks.". The yes-beat of eplp_pleased is eplp_plyes. The no-beat of eplp_pleased is eplp_plno. eplp_pleased summons eplp_plyes, eplp_plno.
eplp_plyes is a beat in EPLP with keyword name "yes" and reaction "She smiles, touching a fingertip delicately to each bristle of the brush, one by one. 'I'm glad,' she says. 'He has been so alone these long years, choosing to forget there were those who remembered him, rather than wonder if they still did.'". eplp_plyes enqueues eplp_lessons.
eplp_plno is a beat in EPLP with keyword name "no" and reaction "She nods somberly, touching a fingertip delicately to each bristle of the brush, one by one. '[if eplp_intyes is spoken]And that in a flash is humanity,' she says, 'always expecting what it does not get. How strange. One would think we'd know ourselves better, by now[else]He was not much of a friend to you, I suppose. And he was not much of a father to Phoebe and me. I think perhaps he gave everything he was and had to my mother. And when she died, he no longer knew how to love anyone but her[end if].'". eplp_plno enqueues eplp_lessons.
eplp_lessons is a beat in EPLP with reaction "With a sudden flick of her wrist, she releases the comb, which twirls away and is swallowed by the void. She looks after it for one wistful moment, then turns to you, taking a step closer.[paragraph break]'There is something about [eplp_wayfaring],' she says, 'which my [eplp_sister] and I learned, but Progue never did, and you may or may not have: there are [eplp_loopholes].' A corner of her mouth rises in a smile.". eplp_lessons suggests eplp_loopholes. eplp_loopholes replaces eplp_lessons.
Understand "wayfaring" as eplp_wayfaring when last beat is in EPLP. eplp_wayfaring is a beat in EPLP with keyword name "wayfaring" and reaction "'We call it The Magic,' she says with a smile, 'Phoebe and I. But I like your word better.'". eplp_wayfaring suggests eplp_loopholes.
Understand "sister" as eplp_sister when last beat is in EPLP. eplp_sister is a beat in EPLP with keyword name "sister" and reaction "'Phoebe takes credit for it, I suppose,' she says, grinning, 'but it was my idea, my theory, to start with.'". eplp_sister suggests eplp_loopholes.
Understand "loophole/loopholes" as eplp_loopholes when last beat is in EPLP. eplp_loopholes is a beat in EPLP with fuse 8 and keyword name "loopholes" and reaction "'At least three,' she says, 'some more obvious than others but all inherent in its nature.'[paragraph break][if player is female]She puts a hand on your forearm and squeezes it briefly[else]She puts a hand to your face and drinks deeply from your eyes for a long moment[end if], then turns away, looking at a simple wooden [o]door[x] which has suddenly appeared in the void.[paragraph break]'One,' she says briskly, 'parents can bring children with them when they wayfare, since the children are their creations. You most likely know this: it's how Phoebe and I came with our father when he sculpted the windsigh tree and we came to Lacuna.'[paragraph break]'Two,' she continues, moving slow but strained towards the door, as if reluctant, 'the Call itself. Saying goodbye to a fellow wayfarer never has to be forever; there is always the chance you will be called to her again, or she to you. And it may not be as random and mysterious as we think. Phoebe and I cannot quite do it at will-- but many times now have we found each other, when we are in need.'[paragraph break]She takes a deep breath, and opens the door; behind it is only more void. 'Three,' she says, carefully. 'You can never go back. But nothing prevents you and another from going the same forward.' She winks, then slips through the door and shuts it behind her.".
After discussing eplp_loopholes: post-conversation processing; move ep2-door to location; continue the action.
An ep2-door is a container. It is closed and fixed in place. The printed name is "simple wooden door". Understand "simple/wooden/door/brass/knob" as ep2-door. The description is "The door is made from unadorned wood, unpainted and unsanded, with a simple brass knob.". Instead of turning ep2-door, try opening ep2-door. Instead of opening ep2-door for the first time: say "You reach forward to open the door, only to discover you are holding [o]something[x]."; move ep2-brush to player. Instead of opening ep2-door: try examining ep2-brush. Check turning ep2-door: try opening ep2-door.
An ep2-brush is a thing. The printed name is "carved brush". Understand "brush/dolphins/lethe's/lethes/handle/something/holding" as ep2-brush. The description is "You open your hand to find it gripping Lethe's brush, the carved dolphins along its handle swimming against the lines and swirls of your hand.[paragraph break]'Tell him,' Lethe's voice comes from somewhere, distant and muffled. 'Tell him we wait for him. Tell him to go forward. Tell him we may yet find each other again.'[paragraph break]The dream fades, and your solid grip on the brush becomes your grip on the waking world.".
A brush-echo is a minor prop with description "You look down into your hand, but the brush is gone-- just a dream.".